*==========================================================
* Micrel MIC4420
*
* This model was developed for Micrel by:
* AEI Systems, LLC
* 5777 W. Century Blvd. Suite 876
* Los Angeles, California 90045
* Copyright 2005, all rights reserved.
*
* This model is subject to change without notice.
* Users may not directly or indirectly re-sell or 
* re-distribute this model. 
*
* For more information regarding modeling services,
* model libraries and simulation products, please
* call AEi Systems at (310) 216-1144, or contact 
* AEi by email: info@aeng.com. http://www.AENG.com
*
* Revision: 3/1/05, version 1.1
**********
*SRC=MIC4420;MIC4420;DRIVERS;MOSFET;  
*SYM=MICDRV
.subckt MIC4420 4  3   9   2 
*               In Out Vcc Gnd
Rin 4 Vind 2k
C1 4 2 6P
D2 2 Vind DN 
D3 4 9 DN 
RT 4 2 10MEG

Vsctl 13 0 DC=5
Sctl 13 VindH Vind 2 _S3_mod 
.MODEL _S3_mod SW VT=1.25 VH=.15 
Rsctl VindH 2 1MEG

I2 9 2 DC=80u
R2 9 2 750k
I1 9 8 DC=330U
R4 9 8 175k
D4 8 9 DN 
.MODEL DN D

BLin 12 2 V=V(VindH) > 2 ? 5 : 0 
Rind 12 10 100 
Cind 10 11 215p 
Vinput 11 2
Bind 10 2 I=7.5-V(9) > 0 ? 0.33*I(Vinput)*(7.5-V(9)) : 0 
Sinput 8 6 10 2 _S1_mod  
.MODEL _S1_mod SW VT=1.45 VH=.65
Rinput 6 2 6k

B3 7 3 V=V(8,2) < 0.5*V(9,2) ? V(9,2) : -V(9,2)
Rout 1 7 100 
Cout 1 2 C=1p*V(9)^2/5.625 < 1p ? 1p : 1p*V(9)^2/5.625 
C2 3 2 50p
M4 9 1 3 3 _M4_mod L=1U W=1.84U 
M5 2 1 3 3 _M5_mod L=1U W=3.366U 
.MODEL _M5_mod PMOS KP=50m RD=1 VTO=-2.3
.MODEL _M4_mod NMOS KP=60m RD=1.6 VTO=1.5
.ENDS
******

