* $Author: Vallabh Chilakapati $
* $Date: 6 Aug 2006 $

* NOTE: - Noise is not modeled.
*       - Temperature is not modeled.
*       - PSR is not modeled.
*       - Model is for single device only.  Simulated supply current is 1/2 of
*         total package current.

* Connections:
*                   Non-Inverting Input
*                   |   Inverting Input
*                   |   |   +ve Voltage Supply
*                   |   |  |   -ve Voltage Supply
*                   |   |  |   |   Output
*                   |   |  |   |   |
.SUBCKT LM258_ON    1   2  11  12  24

***** Input Stage *****
Q_Q1	4 5 6	QPNP1    
Q_Q2	7 8 9	QPNP2
I_I1	111 10	DC 1m
R_RC1	4 12	95.49 
R_RC2	7 12	95.49
R_RE1	10 6	43.79 
R_RE2	10 9	43.79
V_Vio	2 8	0Vdc
E_E4	1 5 16 14	1
E_EVcc	111 0 11 0	1
G_Vcc	0 11	poly(1)	11 0	0.556m 4.8u

***** Gain Stage & Frequency Response Stage *****
R_R3	13 12	1k  
R_R4	111 13	100k  
E_Eref	14 0 13 0	1
G_G1	14 15 7 4 	0.01047
R_Rc	14 15	9.549Meg 
C_Cc	14 15	1.667n 

***** Output Stage *****
E_E1	22 14 15 14	1
V_F1	23 24	0
F_F1	11 0 V_F1 	1
R_Rout	22 23	13

***** Common Mode Rejection *****
R_R1	3 1	1Meg
R_R2	2 3	1Meg
G_G2	14 16 3 14	5.6234n
R_Rcmr	17 16	10k
L_Lcmr	14 17	1.59H 

***** Output Voltage Limiting *****
D_D1	15 18	D10D1
D_D2	19 15	D10D1 
V_Voh	111 18	2.183
V_Vol	19 12	0.639

***** Output Current Limiting *****
D_D3	15 21	D10D1 
D_D4	20 15	D10D1 
V_V3	21 23	-0.207
V_V4	23 20	-0.467

.model QPNP1	PNP(Bf=10841.7)
.model QPNP2	PNP(Bf=11741.7)
.MODEL D10D1 D IS=6E-16 RS=1.000E-3 VJ=.75 BV=100E6
.ENDS
