*-----------------------------------------------------------------------
* Filename:		EH7591A.inc  12/10/03  V1
* Simulator:		LTSpice
* Device type:		Power pentode
* Device model:		EH7591A
*
* Author:		Drew Bolce'
* Date:			12/5/03
* Copyright:		(C)2003-2004 PageRight Co.
*
*
* V1 [12/10/03]: Screen current limited to prevent screen current
*		 draw at Vs = 0.
* 
* The following parameters are not modelled:
*
*   (1) Heater
*   (2) Grid current is an approximation
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to drew@pageright.omc
*
*-----------------------------------------------------------------------
.SUBCKT EH7591A 1 2 3 4 ;  P G1 C G2
+ PARAMS: MU=10.2 EX=1.35 KG1=1460 KG2=4500 KP=48 KVB=12
+         CCG=14P CPG1=.85P CCP=12P RGI=1K 
RE1  7 0  1MEG    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE=  ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LOG(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1   1 3  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)}
G2   4 3  VALUE={(EXP(EX*(LOG((V(4,3)/MU)+V(2,3)))))/KG2}
RCP  1 3  1G      ; FOR CONVERGENCE
C1   2 3  {CCG}    ; CATHODE-GRID 1
C2   1 2  {CPG1}  ; GRID 1-PLATE
C3   1 3  {CCP}   ; CATHODE-PLATE
R1   2 5  {RGI}   ; FOR GRID CURRENT
D3   5 3  DX      ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

.SUBCKT 7195A 1 2 3 4 ;  P G1 C G2
+ PARAMS: MU=16.187 EX=1.768 KG1=1417.55 KG2=4200 KG3=961.81 KP=32 KVB=31.31
+         CCG=14P CPG1=0.4P CCP=10P RGI=1K
RE1  7 0  1MEG    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE={V(4,3)/MU+V(2,3)+V(1,3)/KG3}
G1   1 3  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/(2*KG1)*ATAN(V(1,3)/KVB)}
G2   4 3  VALUE={(EXP(EX*(LOG((V(4,3)/MU)+V(2,3)))))/KG2}
RCP  1 3  1G      ; FOR CONVERGENCE
C1   2 3  {CCG}   ; CATHODE GRID 1
C2   1 2  {CPG1}  ; GRID 1 PLATE
C3   1 3  {CCP}   ; CATHODE PLATE
R1   2 5  {RGI}   ; FOR GRID CURRENT
D3   5 3  DX      ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
